Test de QuickReport 4 Professionnel

QuickReport est fourni sous forme d'un fichier zip qu'il faut décompresser puis installer. Une fois installés les sources des paquets et des composants seront placés dans le dossier C:\program files\QuickReportsX\.
Pour installer le paquet dans Delphi, allez dans le menu Composants puis installer des packages.
Cliquez sur le bouton Ajouter… et sélectionnez le fichier C:\program files\QuickReportsX\QR4DesignDX.bpl.
Une nouvelle palette de composants nommée QReports sera alors disponible.

Pour tester l'installation, il suffit de créer une nouvelle fiche, de placer un composant TQuickRep. Puis de placer un TQRBand et des QRxxx pour placer un texte et une image.
Dans la fiche principale, il suffit d'appeler la méthode :

FenTest1.QuickRep1.PreviewModal;

QuickReport est livré avec un fichier d'aide au format CHM. Pour qu'il soit disponible facilement dans le menu outils de Delphi, nous allons l'ajouter dans la liste.
Dans le menu Outils, sélectionnez Configurer les outils… et cliquez sur Ajouter… :

Ces deux composants ne proviennent pas de QuSoft, mais de Steema Software concepteur de la suite de composants TeeChart.

Les sources des deux composants manquants sont disponibles sur cette page :
TeeChart V4 files for QuickReport.
Téléchargez les sources donnés pour Quick Report 3 et Delphi 7 puis extraire les fichiers du ZIP dans le répertoire C:\Program Files\QuickReportsX.

Ouvrez le source du paquet d'exécution C:\Program Files\QuickReportsX\TeeQR.dpk.
Il faut modifier la liste des paquets requis en remplaçant QRpt par QR4RunDX :

requires
  vcl,
  vcldb,
  QR4RunDX,
  Tee,
  TeeDB,
  TeeUI;

Il faut aussi modifier la version des bibliothèques utilisées : (toujours dans le source du projet)

// Remplacez :
{$LIBSUFFIX '70'}
// par :
{$LIBSUFFIX '90'}

Vous pouvez maintenant compiler le paquet (aucune erreur ne doit apparaître normalement).

Ouvrez ensuite le source du paquet de conception C:\Program Files\QuickReportsX\DclTQR.dpk.
Supprimez la ligne {$R *.res} dans le source du projet, sinon il ne sera pas possible de compiler le paquet à cause d'une ressource dupliquée.
Il faut de même changer la version des bibliothèques utilisées :

// Remplacez :
{$LIBSUFFIX '70'}
// par :
{$LIBSUFFIX '90'}

Vous pouvez maintenant construire et installer le paquet sans erreur.
Un nouveau composant doit alors être recensé : TQRChart.

Ce composant très simple d'utilisation est l'une des grandes nouveautés de cette version. Il permet de créer un ensemble de données virtuelles afin de simplifier tous les problèmes de connexion aux bases de données.

Ce composant comporte une liste de champs comme n'importe quel ensemble de données. Les valeurs de ces champs seront données par un événement de ce composant au fur et à mesure que l'état réclame des valeurs. Ce système simple permet d'utiliser un état standard et de gérer complètement par code les valeurs envoyées à l'état. Il devient donc très facile de créer un état à partir d'un fichier texte, d'un fichier XML ou directement d'une suite de calculs.

Mise en œuvre

À titre d'exemple nous allons créer une table virtuelle contenant les champs suivants :

En utilisant le tableau ci-dessus, on met à jour la propriété FieldDefs du composant.

Il faut ensuite donner le code de gestion de l'événement OnSetFieldValue.

Paramètre de l'événement OnSetFieldValue

• Field : champ pour lequel la valeur est demandée.
• Buffer : tampon servant à stocker la valeur du champ.
• MoreData : test de fin de table, il faut retourner True sur tous les enregistrements sauf le dernier où il faut retourner False.

En fonction du nom du champ passé en appel de la fonction, il faut retourner dans Buffer la valeur correspondante.

procedure TForm1.QRAbsTable1SetFieldValue(const DataStr: string; Field: TField;
  buffer: Pointer; var MoreData: Boolean);
var
  UnReel   : double;
  UnEntier : integer;
  UneDate  : TDateTime;
begin
  // Le premier champ est un entier
  If Field.FieldName='Numero' Then
  Begin
    UnEntier := QRAbsTable1.RecNo;
    CopyMemory( buffer, @UnEntier, SizeOf(UnEntier));
  End;
  // Le deuxième champ est une chaîne
  If Field.FieldName='Nom' Then
  Begin
    StrCopy(Buffer,Pchar(NombreEnLettres(QRAbsTable1.RecNo)));
  End;
  // Le troisième champ est une valeur numérique
  If Field.FieldName='Racine' Then
  Begin
    UnReel := SQRT(QRAbsTable1.RecNo);
    CopyMemory( Buffer, @UnReel, sizeof(UnReel));
  End;
  // Le quatrième champ est une date
  If Field.FieldName='Quand' Then
  Begin
    UneDate := EncodeDate(2005,1,1)+QRAbsTable1.RecNo-1;
    CopyMemory( Buffer, @UneDate, sizeof(UneDate));
  End;
  // Test de fin de parcours de la table
  MoreData := QRAbsTable1.RecNo < 365;
end;

Une fois ceci défini, il faut mettre la propriété Active à True afin que la liste des champs soit disponible dans la conception des états.

À partir de cet ensemble de données, nous allons réaliser un état simple affichant simplement la table en entier. Pour ce faire, il suffit de procéder comme n'importe quel état QuickReport et en utilisant FenPrinc.QRAbsTable1 comme source de données.

La fenêtre de prévisualisation a été revue pour y ajouter deux fonctionnalités intéressantes.

L'onglet Vignettes permet d'accéder rapidement aux pages de l'état.

La deuxième fonctionnalité est la recherche d'un texte dans l'état. Il suffit d'utiliser le bouton rechercher puis de visualiser la liste des pages contenant l'occurrence dans l'onglet Recherche.
Il suffit ensuite de cliquer dans la liste pour visualiser la page concernée.

Il est maintenant possible d'ajouter une image de fond sur un état et de gérer quels éléments seront transparents.

Pour mettre une image de fond, ajouter un composant TQRImage sur le TQuickRep (et non pas sur une bande).
Il faut donner au composant les dimensions et la position voulues sur la page, il n'est pas automatiquement ajusté à la taille de la page.
Dans le composant QuickRep il faut ensuite donner dans la propriété BackImageControl le nom du composant servant d'image de fond.

Un exemple de page générée avec une image de fond est donné ici :
https://nono40.developpez.com/tutoriel/delphi/quickreport/fichiers/essaiimages.html

Notez que cette possibilité améliore beaucoup l'aspect visuel des documents.

Ceci fonctionne avec les états sur sortie graphique : imprimés, PDF, WMF et HTML.

Les TQRRichText sont maintenant exportés dans les états graphiques. Ils sont intégrés en tant qu'image.
Dans les fichiers PDF les images sont incluses directement, dans les fichiers HTML les images sont incluses en fichiers séparés.

Le nom des fichiers image générés est le nom des composants TQRRichText allongé d'un indice incrémental afin qu'un RichText situé sur une bande puisse avoir une image différente sur chaque image de la bande.

Un exemple de page générée avec des TQRRichText :
https://nono40.developpez.com/tutoriel/delphi/quickreport/fichiers/essaiimages.html

La version 3.0 standard ne comportait que trois filtres : TXT, CSV et HTML. De nouveaux filtres sont désormais disponibles et le filtre HTML a été amélioré.

Pour les différents essais, nous allons utiliser la table abstraite du premier test. Sur l'état un exemplaire de chaque filtre va être déposé afin de pouvoir exporter l'état sous ses différentes formes.

À noter qu'il suffit de poser un composant filtre sur un rapport quelconque pour que le filtre soit disponible pour tous les états de l'application.

III-E-1. Filtre PDF▲

Uses QRPDFFilt
//...
procedure TForm1.btnPDFClick(Sender: TObject);
Var expFilt : TQRPDFDocumentFilter;
begin
  expFilt := TQRPDFDocumentFilter.create( 'D:\TEMP\QR\essai.pdf' );
  Try
    FenTest2.QuickRep1.ExportToFilter( expFilt );
  Finally
    expFilt.free;
  End;
end;

III-E-2. Filtre Excel▲

Uses QRExport;
//...
procedure TForm1.btnXLSClick(Sender: TObject);
Var expFilt : TQRExcelFilter;
begin
  expFilt := TQRExcelFilter.create( 'D:\TEMP\QR\essai.xls' );
  Try
    FenTest2.QuickRep1.ExportToFilter( expFilt );
  Finally
    expFilt.free;
  End;
end;

III-E-3. Filtre WMF▲

procedure TForm1.btWMFClick(Sender: TObject);
Var expFilt : TQRWMFExportFilter;
begin
  expFilt := TQRWMFExportFilter.create( 'D:\TEMP\QR\essai.wmf' );
  Try
    With FenTest2.QuickRep1 Do
    Begin
      Prepare;
      QrPrinter.ExportToFilter(expFilt);
      QrPrinter.Free;
      QrPrinter := nil;
    End;
  Finally
    expFilt.free;
  End;
end;

III-E-4. Filtre CSV▲

procedure TForm1.btnCSVClick(Sender: TObject);
Var expFilt : TQRCommaSeparatedFilter;
begin
  expFilt := TQRCommaSeparatedFilter.create( 'D:\TEMP\QR\essai.csv' );
  Try
    FenTest3.QuickRep1.ExportToFilter( expFilt );
  Finally
    expFilt.free;
  End;
end;

III-E-5. Filtre HTML▲

procedure TForm1.btnHTMClick(Sender: TObject);
Var expFilt : TQRGHTMLDocumentFilter;
begin
  // On fixe le répertoire par défaut
  Chdir('D:\TEMP\QR\ESSAI\');
  // On crée un composant et on génère les pages
  expFilt := TQRGHTMLDocumentFilter.create( 'essai.html' );
  expFilt.MultiPage := True;
  expFilt.PageLinks := True;
  Try
    FenTest2.QuickRep1.ExportToFilter( expFilt );
  Finally
    expFilt.free;
  End;
end;

III-E-6. Filtre XML▲

procedure TForm1.btnXMLClick(Sender: TObject);
var xdoc : TQRXDocumentFilter;
begin
  xdoc := TQRXDocumentFilter.Create('D:\TEMP\QR\essai.xml');
  Try
    xdoc.Author := 'Nono40';
    xdoc.title := 'Test d''export XML/XSL';
    xdoc.Copyright := '(c) 2005 Bruno Guérangé';
    xdoc.XLStyleURL := 'essai.xsl';
    xdoc.XLEncoding := 'ISO-8859-1';
    xdoc.CompressImages := false;
    FenTest2.QuickRep1.exporttofilter( xdoc );
  Finally
    xdoc.free;
  End;
end;

Les rapports composés peuvent maintenant être exportés à l'aide des filtres. Seuls les filtres XML, PDF et HTML sont supportés pour le moment.

Pour réaliser un rapport composé, il faut placer sur une fiche un composant TQRCompositeReport puis définir dans son événement OnAddReports la liste des rapports à ajouter.
Par exemple pour ajouter trois rapports séparés :

  With QRCompositeReport1.Reports Do
  Begin
    Add(FenRapport1.QuickRep1);
    Add(FenRapport2.QuickRep1);
    Add(FenRapport3.QuickRep1);
  End;

Il est ensuite possible d'effectuer une prévisualisation avec la méthode Preview, une impression avec la méthode Print ou une exportation avec la méthode ExportToFilter.

Par exemple pour créer un fichier PDF :
./fichiers/essaicomp.pdf

procedure TForm1.btnCompPDFClick(Sender: TObject);
Var expFilt : TQRPDFDocumentFilter;
begin
  expFilt := TQRPDFDocumentFilter.create( 'D:\TEMP\QR\essaicomp.pdf' );
  Try
    QRCompositeReport1.ExportToFilter( expFilt );
  Finally
    expFilt.free;
  End;
end;

Et pour créer des pages HTML :
https://nono40.developpez.com/tutoriel/delphi/quickreport/fichiers/essaicomp1.html

procedure TForm1.btnCompHTMClick(Sender: TObject);
Var expFilt : TQRGHTMLDocumentFilter;
begin
  Chdir('D:\TEMP\QR\ESSAI\');
  expFilt := TQRGHTMLDocumentFilter.create( 'essaicomp.html' );
  expFilt.MultiPage := True;
  expFilt.PageLinks := True;
  expFilt.LinkFontSize := 12;
  Try
    QRCompositeReport1.ExportToFilter( expFilt );
  Finally
    expFilt.free;
  End;
end;