Réalisation d'un écran de veille avec Delphi

Date de publication : 23/09/2004

Par Nono40 (nono40.developpez.com)
 

Cet article présente la méthode pour la réalisation d'un écran de veille simple avec Delphi.

I. Principe

I-A. Ecran de veille, simple exécutable

I-B. Affichage normal de l'écran de veille

I-C. Configuration de l'écran de veille

I-D. Prévisualisation de l'écran de veille

Attention, la prévisualisation est l'affichage dans le petit moniteur de la fenêtre des propriétés d'affichage du bureau. Le bouton "tester" de cette même fenêtre ne fait que lancer l'écran de veille normalement avec la commande S.

Vous pouvez vous-aussi afficher dans une fenêtre Delphi n'importe quel écran de veille, voir Prévisualisation d'un écran de veille.

I-E. Modification du mot de passe

I-F. Signaler au système qu'il est en veille

I-G. Application mono-instance, quoi-que...

II. Réalisation

II-A. Données globales

unit Declare;

interface

Type TssMode = ( ssAffiche , ssConfig , ssMotDePasse , ssPrevisu );

Var
  // Mode de fonctionnement de l'application
  ssMode      : TssMode = ssAffiche;

  // Valeur des paramètres passés au programme
  Param1      : String;
  Param2      : String;

  // Valeur de déplacement de l'image
  DecX        : Integer = 3;
  DecY        : Integer = 3;

  // Option contenant la vitesse en cours.
  optVitesse  : Integer = 100;

Procedure LitIni;
Procedure EcritIni;

implementation

Uses IniFiles,SysUtils;

Procedure LitIni;
Var Ini:TInifile;
Begin
  Ini:=TIniFile.Create(ExtractFilePath(ParamStr(0))+'CONFIG.INI');
  Try
    optVitesse := Ini.ReadInteger('ECRAN','Vitesse',optVitesse);
  Finally
    Ini.Free;
  End;
End;

Procedure EcritIni;
Var Ini:TInifile;
Begin
  Ini:=TIniFile.Create(ExtractFilePath(ParamStr(0))+'CONFIG.INI');
  Try
    Ini.WriteInteger('ECRAN','Vitesse',optVitesse);
  Finally
    Ini.Free;
  End;
End;

end.

II-B. Fenêtre de visualisation de l'écran de veille

• BorderStyle : bsNone ( obligatoire )
• FormStyle : fsStayOnTop ( obligatoire )
• WindowState : wsMaximized ( obligatoire )
• Color : clBlack

procedure TFenEcran.FormCreate(Sender: TObject);
begin
  // Lecture des paramètres de configuration
  LitIni;
  Timer.Interval := optVitesse;
  // Suppression du curseur
  cursor:=crNone;
end;

• uiAction : Identificateur du paramètre à modifier, ici SPI_SCREENSAVERRUNNING
• uiParam : Valeur du paramètre : 1 si l'écran de veille est actif, 0 sinon
• pvParam : Pointeur vers un entier ( inutilisé dans ce cas )
• fWinIni : Mettre 1 pour modifier le fichier WinIni, dans notre cas il faut mettre 0

procedure TFenEcran.FormShow(Sender: TObject);
Var i:Integer;
begin
  // On masque l'application dans la barre des tâches
  ShowWindow(Application.Handle,SW_HIDE);
  // On dit au système que l'on est en mode veille
  SystemParametersInfo(SPI_SCREENSAVERRUNNING,1,@i,0);
end;

procedure TFenEcran.TimerTimer(Sender: TObject);
begin
  // Code de déplacement de l'image
  Image.Left := Image.Left + DecX;
  Image.Top := Image.Top + DecY;
  If (Image.Left + Image.Width)>=ClientWidth Then DecX := -3;
  If (Image.Top + Image.Height)>=ClientHeight Then DecY := -3;
  If Image.Left <= 0 Then DecX := 3;
  If Image.Top  <= 0 Then DecY := 3;
end;

procedure TFenEcran.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  // Sur un click on ferme l'écran de veille
  Close;
end;

procedure TFenEcran.FormClose(Sender: TObject; var Action: TCloseAction);
Var i:Integer;
begin
  // On dit au système qu'il n'est plus en mode veille
  SystemParametersInfo(SPI_SCREENSAVERRUNNING,0,@i,0);
end;

II-C. Modification du source du projet

program Project1;

uses
  Windows,
  Forms,
  SysUtils,
  Declare in 'Declare.pas',
  UEcran in 'UEcran.pas' {FenEcran};

// Modification de l'extension
{$E SCR}
{$R *.res}
// Déclaration du nom de l'écran de veille
{$D SCRNSAVE Ecran de veille de Nono}

begin
  // On commence par prendre les paramètres passés au programme
  Param1 := Copy(UpperCase(ParamStr(1)),1,2);
  Param2 := UpperCase(ParamStr(2));

  // On filtre le premier afin de ne garder que la lettre
  If (Length(Param1)>0)And Not (Param1[1] In ['A'..'Z']) Then
    Param1 := Copy(Param1,2,1);

  // On détermine ce qu'il faut faire en fonction de Param1
  If Param1='P' Then ssMode := ssPrevisu;
  If Param1='C' Then ssMode := ssConfig;
  If Param1='S' Then ssMode := ssAffiche;
  If Param1='A' Then ssMode := ssMotDePasse;

  // Une application écran de veille doit être mono-instance
  SetLastError(NO_ERROR);
  CreateMutex (nil, False, 'MONSCREENSAVER');
  if GetLastError = ERROR_ALREADY_EXISTS Then Exit;

  // Traitement en fonction des cas
  Case ssMode Of
    ssAffiche,ssPrevisu:
    Begin
      Application.Initialize;
      Application.CreateForm(TFenEcran, FenEcran);
      if ssMode=ssPrevisu Then
        FenEcran.ParentWindow := StrToInt(Param2);
      Application.Run;
    End;
  End;
end.

II-D. Ajout d'une fenêtre de configuration

procedure TFenConfig.FormShow(Sender: TObject);
begin
  // Lecture et affichage des paramètres
  LitIni;
  seTimer.Value := optVitesse;
  // On masque l'application dans la barre des tâches
  ShowWindow(Application.Handle,SW_HIDE);
end;

procedure TFenConfig.btnAnnulerClick(Sender: TObject);
begin
  // Pour annuler, on ferme simplement...
  Close;
end;

procedure TFenConfig.btnOKClick(Sender: TObject);
begin
  // En cas de validation il faut sauver les paramtres
  optVitesse := seTimer.Value;
  EcritIni;
  // Puis fermer la fenêtre
  Close;
end;

  // Traitement en fonction des cas
  Case ssMode Of
    ssAffiche,ssPrevisu:
    Begin
      Application.Initialize;
      Application.CreateForm(TFenEcran, FenEcran);
      if ssMode=ssPrevisu Then
        FenEcran.ParentWindow := StrToInt(Param2);
      Application.Run;
    End;
    ssConfig:
    Begin
      Application.CreateForm(TFenConfig,FenConfig);
      Application.Initialize;
      Application.Run;
    End;
  End;

II-E. Gestion du mot de passe

  // Traitement en fonction des cas
  Case ssMode Of
    ssMotDePasse:Begin
      MdpLib := LoadLibrary('MPR.DLL');
      If MdpLib <> 0 Then
      Begin
        MdpFunc := GetProcAddress(MdpLib,'PwdChangePasswordA');
        If Assigned(MdpFunc) Then
          MdpFunc('SCRSAVE',StrToInt(Param2),0,0);
        FreeLibrary(MdpLib);
      End;
      Exit;
    End;
  End;

  // Une application écran de veille doit être mono-instance
  SetLastError(NO_ERROR);
  CreateMutex (nil, False, 'MONSCREENSAVER');
  if GetLastError = ERROR_ALREADY_EXISTS Then Exit;

  // Traitement en fonction des cas
  ...

procedure TFenEcran.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
Var Reg:TRegistry;
    MdpFunc   : function (Parent : THandle) : Boolean; stdcall;
    MdpLib  : THandle;

begin
  // On teste le mot de passe éventuel dans le cas de demande de fermeture de la fiche
  CanClose := True;
  If ssMode=ssAffiche Then
  Try
    // Test seulement en affichage normal
    Reg := TRegistry.Create;
    Try
      // Lecture de la clef
      Reg.RootKey := HKEY_CURRENT_USER;
      If Reg.OpenKey('Control Panel\Desktop',False) Then
        If Reg.ReadInteger('ScreenSaveUsePassword') <> 0 Then
        Begin
          MdpLib := LoadLibrary('PASSWORD.CPL');
          If MdpLib <> 0 Then
          Begin
            // Appel de la procédure de demande de mot de passe
            MdpFunc := GetProcAddress(MdpLib,'VerifyScreenSavePwd');
            CanClose := MdpFunc(Handle);
            FreeLibrary(MdpLib);
          End;
        End;
    Finally
      Reg.Free;
    End;
  Except
    // Sur erreur, par défaut on ferme.
    CanClose:=True;
  End;
end;

Sous Windows XP la clef n'existe pas. La gestion du mot de passe est effectuée par Windows directement en affichant la fenêtre d'ouverture de session.

III. Conclusion

Voir également mes autres articles :

Utiliser Delphi 2005 comme éditeur HTML

Utilisation du correcteur orthographique de Word dans Delphi.

Utiliser l'assembleur en ligne avec Delphi

Utilisation de la propriété TBitmap.ScanLine

Utilisation de TComPort sous Delphi 2005 ( Win 32 )

Installation des composants SynEdit sous Delphi 2005 ( Win 32 )

Réalisation d'un écran de veille avec Delphi

Articles sur Delphi pour .NET

Conversion des pointeurs d'enregistrement sous Delphi .NET

Utilisation des fichiers typés sous Delphi .NET

Utilisation de la classe NotifyIcon dans Delphi .NET

Création d'un contrôle Winform avec Delphi .NET

Programmation réseau avec Delphi pour .NET

Tests et outils

Outil : Test de QuickReport 4 Professionnel

Consultez aussi les sources Delphi :

Les sources de Nono40