Utilisation de la classe NotifyIcon dans Delphi 8

Date de publication : 16/02/2004 , Date de mise a jour : 16/02/2004

Par Nono40 (nono40.developpez.com)
 

Ce document présente l'utilisation du composant Winform NotifyIcon dans une application Delphi.NET. Cette présentation sera appliquée aux applications Winform et VCL.NET.

Introduction

I. Principes communs

I-A. Classe NotifyIcon

• Text : Texte affiché sous forme de Hint quand la souris est au dessus de l'icône.
• Icon : Objet System.Drawing.Icon contenant le dessin de l'icône.
• ContextMenu : Objet System.Windows.Forms.ContextMenu contenant le menu contextuel.
• Visible : Tout simplement indique si l'icône doit être affichée ou non.

• Click : Déclenché quand l'utilisateur clique sur l'icône.
• DoubleClick : Déclenché quand l'utilisateur double-clique sur l'icône.
• MouseDown : Déclenché quand l'utilisateur appuie sur un bouton de la souris au-dessus de l'icône.
• MouseUp : Déclenché quand l'utilisateur relache un bouton de la souris au-dessus de l'icône.
• MouseMove : Déclenché quand l'utilisateur déplace la souris au-dessus de l'icône.

I-B. Utilisation de l'icône.

• Affichage d'une icône.
• Gestion des trois types de click : gauche, droit et double
• Gestion d'un menu contextuel

II. Utilisation dans une application Winform

II-A. Mise en place des composants

II-B. Ajout du code en réponse aux événements

procedure TWinForm.MenuReduire_Click(sender: System.Object; e: System.EventArgs);
begin
  // L'option réduire permet de ... réduire la fenêtre !
  WindowState:=FormWindowState.Minimized;
end;

procedure TWinForm.MenuRestaurer_Click(sender: System.Object; e: System.EventArgs);
begin
  // L'option restaurer permet de ... restaurer la fenêtre !
  If WindowState=FormWindowState.Minimized
    Then WindowState:=FormWindowState.Normal;
  Show;
end;

procedure TWinForm.MenuFermer_Click(sender: System.Object; e: System.EventArgs);
begin
  // Fermer la fenêtre
  Close;
end;

procedure TWinForm.NotifyIcon1_MouseDown(sender: System.Object; e: System.Windows.Forms.MouseEventArgs);
begin
  // Dans le cas d'un click gauche sur l'icone, on test si c'est le premier
  // click puis on lance le timer de retard d'affichage du menu.
  // Cette méthode permet de laisser le temps de double cliquer sur l'icone
  // avant que le menu n'apparaisse.
  If (e.Button=System.Windows.Forms.MouseButtons.Left) And
     (e.Clicks=1)
  Then
    Timer1.Enabled:=True;
end;

procedure TWinForm.NotifyIcon1_DoubleClick(sender: System.Object; e: System.EventArgs);
begin
  // Dans le cas d'un double-click, on arrête le timer lancé par le premier
  // click et on effectue l'action par défaut.
  Timer1.Enabled:=False;
  MenuRestaurer_Click(Sender,e);
end;

procedure TWinForm.Timer1_Tick(sender: System.Object; e: System.EventArgs);
begin
  // Si le timer s'est écoulé, c'est qu'il n'y a pas eu de double-click.
  // Dans ce cas on affiche le menu là ou est la souris.
  Timer1.Enabled:=False;
  ContextMenu1.Show(Self,Control.MousePosition);
end;

II-C. Exécution

III. Utilisation dans une application VCL.NET

III-A. Création d'une instance de le classe NotifyIcon

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, System.Windows.Forms,System.Drawing;

  TForm1 = class(TForm)
    ...
  private
    { Private declarations }
    // Il faut déclarer manuellement le composant WinForm
    NotifyIcon1: NotifyIcon;
    // Ainsi que les événement associés
    procedure NotifyIcon1_DoubleClick(sender: System.Object; e: System.EventArgs);
    procedure NotifyIcon1_MouseDown(sender: System.Object; e: System.Windows.Forms.MouseEventArgs);
  public
    { Public declarations }
  end;

// Redéclaration de la fonction ExtractIco, celle de Windows.pas n'étant pas correcte.
[DllImport('Shell32.dll', CharSet = CharSet.Auto, SetLastError = True, EntryPoint = 'ExtractIconEx')]
function ExtractIco(lpszFile: string; nIconIndex: Integer;
  out phiconLarge:IntPtr;out phiconSmall: IntPtr; nIcons: UINT): UINT; external;

procedure TForm1.FormCreate(Sender: TObject);
begin
  // L'instance de la classe NotifyIcon doit être créée dynamiquement
  // car les composants WinForm ne peuvent être déposés sur des fiches
  // VCLForm.
  NotifyIcon1:=System.Windows.Forms.NotifyIcon.Create;
  NotifyIcon1.Text:='Nono40 - Source 79';

  // Si l'icone est celle de l'exécutable
  ExtractIco(Forms.Application.ExeName,0,Large,Small,1);
  NotifyIcon1.Icon:=System.Drawing.Icon.FromHandle(Large);

  // Association des méthodes aux événements correspondants. Notez ici
  // la différence importante avec Delphi 7. Les événements sont ajoutés
  // dans la liste des événements. Ce n'est plus une simple affectation
  // d'adresse de méthode.
  Include(NotifyIcon1.DoubleClick,NotifyIcon1_DoubleClick);
  Include(NotifyIcon1.MouseDown  ,NotifyIcon1_MouseDown);
  // L'icône est affichée dans la barre de stâches
  NotifyIcon1.Visible:=True;
end;

  // Si l'icône est lue dans un fichier placé à coté de l'exécutable
  NotifyIcon1.Icon:=System.Drawing.Icon.Create('Nono.ico');

  // Si l'icone est stockée dans un TImage sur la fiche
  Ico:=IntPtr.Create(Image1.Picture.Icon.Handle);
  NotifyIcon1.Icon:=System.Drawing.Icon.FromHandle(Ico);

procedure TForm1.FormDestroy(Sender: TObject);
begin
  // L'instance est créée sans propriétaire, donc ne pas
  // oublier de la détruire.
  NotifyIcon1.Free;
end;

III-B. Ajout des autres composants

III-C. Ajout du code en réponse aux événements

procedure TForm1.MenuReduireClick(Sender: TObject);
begin
  // L'option réduire permet de ... réduire la fenêtre !
  WindowState:=wsMinimized;
end;

procedure TForm1.MenuRestaurerClick(Sender: TObject);
begin
  // L'option restaurer permet de ... restaurer la fenêtre !
  WindowState:=wsNormal;
end;

procedure TForm1.MenuFermerClick(Sender: TObject);
begin
  // Fermer la fenêtre
  Close
end;

procedure TForm1.NotifyIcon1_MouseDown(sender: TObject;
  e: System.Windows.Forms.MouseEventArgs);
begin
  // Dans le cas d'un click gauche, on lance le timer pour
  // différencier le click, d'un double-click.
  If e.Button=System.Windows.Forms.MouseButtons.Left Then
    Timer1.Enabled:=True;
  // Dans le cas d'un click droit on affiche le menu.
  If e.Button=System.Windows.Forms.MouseButtons.Right Then
    PopUpMenu1.Popup(Mouse.CursorPos.X,Mouse.CursorPos.Y);
end;

procedure TForm1.NotifyIcon1_DoubleClick(sender: TObject;
  e: System.EventArgs);
begin
  // Dans le cas d'un double-click, on arrête le timer lancé par le premier
  // click et on effectue l'action par défaut.
  Timer1.Enabled:=False;
  MenuRestaurerClick(Nil);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  // Si le timer s'est écoulé, c'est qu'il n'y a pas eu de double-click.
  // Dans ce cas on affiche le menu là ou est la souris.
  Timer1.Enabled:=False;
  PopUpMenu1.Popup(Mouse.CursorPos.X,Mouse.CursorPos.Y);
end;

III-D. Exécution

Conclusion

Tests et outils

Outil : Les nouveautés de Delphi 2009

Outil : Test de QuickReport 4 Professionnel

Voir également mes autres articles :

Utiliser Delphi 2005 comme éditeur HTML

Utilisation du correcteur orthographique de Word dans Delphi.

Utiliser l'assembleur en ligne avec Delphi

Utilisation de la propriété TBitmap.ScanLine

Utilisation de TComPort sous Delphi 2005 ( Win 32 )

Installation des composants SynEdit sous Delphi 2005 ( Win 32 )

Réalisation d'un écran de veille avec Delphi

Article sur les automates programmables

Configurer un variateur ATV71 sur un réseau Profibus avec PL7

Articles sur Delphi pour .NET

Conversion des pointeurs d'enregistrement sous Delphi .NET

Utilisation des fichiers typés sous Delphi .NET

Utilisation de la classe NotifyIcon dans Delphi .NET

Création d'un contrôle Winform avec Delphi .NET

Programmation réseau avec Delphi pour .NET

Consultez aussi les sources Delphi :

Les sources de Nono40